0a65e4124a
Add a new qemu_api module, `vmstate`. Declare a bunch of Rust macros declared that are equivalent in spirit to the C macros in include/migration/vmstate.h. For example the Rust of equivalent of the C macro: VMSTATE_UINT32(field_name, struct_name) is: vmstate_uint32!(field_name, StructName) This breathtaking development will allow us to reach feature parity between the Rust and C pl011 implementations. Extracted from a patch by Manos Pitsidianakis (https://lore.kernel.org/qemu-devel/20241024-rust-round-2-v1-4-051e7a25b978@linaro.org/). Signed-off-by: Manos Pitsidianakis <manos.pitsidianakis@linaro.org> Signed-off-by: Paolo Bonzini <pbonzini@redhat.com>
47 lines
1.2 KiB
Meson
47 lines
1.2 KiB
Meson
_qemu_api_rs = static_library(
|
|
'qemu_api',
|
|
structured_sources(
|
|
[
|
|
'src/lib.rs',
|
|
'src/definitions.rs',
|
|
'src/device_class.rs',
|
|
'src/vmstate.rs',
|
|
'src/zeroable.rs',
|
|
],
|
|
{'.' : bindings_rs},
|
|
),
|
|
override_options: ['rust_std=2021', 'build.rust_std=2021'],
|
|
rust_abi: 'rust',
|
|
rust_args: [
|
|
'--cfg', 'MESON',
|
|
# '--cfg', 'feature="allocator"',
|
|
],
|
|
)
|
|
|
|
qemu_api = declare_dependency(
|
|
link_with: _qemu_api_rs,
|
|
dependencies: qemu_api_macros,
|
|
)
|
|
|
|
# Rust executables do not support objects, so add an intermediate step.
|
|
rust_qemu_api_objs = static_library(
|
|
'rust_qemu_api_objs',
|
|
objects: [libqom.extract_all_objects(recursive: false),
|
|
libhwcore.extract_all_objects(recursive: false)])
|
|
|
|
test('rust-qemu-api-integration',
|
|
executable(
|
|
'rust-qemu-api-integration',
|
|
'tests/tests.rs',
|
|
override_options: ['rust_std=2021', 'build.rust_std=2021'],
|
|
rust_args: ['--test'],
|
|
install: false,
|
|
dependencies: [qemu_api, qemu_api_macros],
|
|
link_whole: [rust_qemu_api_objs, libqemuutil]),
|
|
args: [
|
|
'--test',
|
|
'--format', 'pretty',
|
|
],
|
|
protocol: 'rust',
|
|
suite: ['unit', 'rust'])
|